#!/home/eric/bin/perl

# mylibrary2oai.pl - export the contents of a MyLibrary database to sets of OAIXML files

# Eric Lease Morgan <emorgan@nd.edu>
# June 24, 2007 - added full dublin core to the output
# June 23, 2007 - first investigations; based on CRRI

use constant DIRECTORY => '/home/eric/apache/htdocs/oai/data/';

use MyLibrary::Core;
use strict;

# get all facets and loop through them
my @facets = MyLibrary::Facet->get_facets( sort => 'name' );
foreach my $facet ( @facets ) {
	
	# get all terms associated with this facet, and loop through them
	foreach my $term_id ( $facet->related_terms( sort => 'name' )) {
	
		# create a term directory
		my $term = MyLibrary::Term->new( id => $term_id );
		my $term_directory = DIRECTORY . &directify( $term->term_name ) . '/';
		print $term->term_name . " ($term_directory)\n";
		if ( ! -e $term_directory ) { mkdir $term_directory or die "Can't create $term_directory ($!)\n" }

		# get all the resources with this term, and loop through them
		foreach my $resource_id ( $term->related_resources( sort => 'name' )) {
		
			# get the required data
			my $resource    = MyLibrary::Resource->new( id => $resource_id );
			my $content;
			if ( $resource->contributor ) { $content .= '<contributor>' . &escape( $resource->contributor ) . '</contributor>' }
			if ( $resource->coverage )    { $content .= '<coverage>'    . &escape( $resource->coverage )    . '</coverage>' }
			if ( $resource->creator )     { $content .= '<creator>'     . &escape( $resource->creator )     . '</creator>' }
			if ( $resource->date )        { $content .= '<date>'        . &escape( $resource->date )        . '</date>' }
			if ( $resource->note )        { $content .= '<description>' . &escape( $resource->note )        . '</description>' }
			if ( $resource->format )      { $content .= '<format>'      . &escape( $resource->format )      . '</format>' }
			if ( $resource->fkey )        { $content .= '<identifier>'  . &escape( $resource->fkey )        . '</identifier>' }
			
			foreach my $location ( $resource->resource_locations ) { $content .= '<identifier>' . &escape( $location->location ) . '</identifier>' }

			if ( $resource->language )    { $content .= '<language>'    . &escape( $resource->language )    . '</language>' }
			if ( $resource->publisher )   { $content .= '<publisher>'   . &escape( $resource->publisher )   . '</publisher>' }
			if ( $resource->relation )    { $content .= '<relation>'    . &escape( $resource->relation )    . '</relation>' }
			if ( $resource->rights )      { $content .= '<rights>'      . &escape( $resource->rights )      . '</rights>' }
			if ( $resource->source )      { $content .= '<source>'      . &escape( $resource->source )      . '</source>' }
			if ( $resource->rights )      { $content .= '<rights>'      . &escape( $resource->rights )      . '</rights>' }
			if ( $resource->subject )     { $content .= '<subject>'     . &escape( $resource->subject )     . '</subject>' }
			if ( $resource->name )        { $content .= '<title>'       . &escape( $resource->name )        . '</title>' }
			if ( $resource->type )        { $content .= '<type>'        . &escape( $resource->type )        . '</type>' }
			
			my $filename = 'mylibrary-'    . $resource->id . '.xml';
			print "\t\t" . $resource->name . " ($filename)\n";
			
			# open, write, and close an oaixml file
			open OAI, " > $term_directory$filename" or die "Can't open $filename ($!)\n";
			print OAI <<EOR;
<?xml version="1.0" encoding="UTF-8"?>

<oaidc:dc xmlns="http://purl.org/dc/elements/1.1/" 
	xmlns:oaidc="http://www.openarchives.org/OAI/2.0/oai_dc/" 
	xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
	xsi:schemaLocation="http://www.openarchives.org/OAI/2.0/oai_dc/
	http://www.openarchives.org/OAI/2.0/oai_dc.xsd">
				  
	$content

</oaidc:dc>
EOR
			close OAI;
	
		}
				
	}
		
}


sub directify {

	my $s = shift;
	$s = lc( $s );
	while ( $s =~ / / ) { $s =~ s/ /_/g }
	return $s;

}


sub escape {

	my $s = shift;
	$s =~ s/&/&amp;/g;
	$s =~ s/</&lt;/g;
	$s =~ s/>/&gt;/g;
	return $s;

}